0 GOTO800
1 P=12348:PS=P+1024
2 S=0:PRINTCHR$(11)
3 M=4
7 R1$="Outerlimits":R2$="*Space-Collision*"
25 PRINT"       PRESS ANY KEY TO START...."
26 IFINKEY$=""THEN26
27 PRINTCHR$(11)
30 FORA=13312TO14311:POKEA,48:NEXTA
50 FORA=1TO10:X=INT(RND(1)*900)+12418
60 POKEX,157:NEXTA
100 K$=INKEY$:IFK$="h"THEN200
110 IFK$="g"THEN300
120 IFK$="q"THEN400
130 IFK$="z"THEN500
140 IFK$=""THEN160
150 GOTO100
160 ONMGOTO200,300,400,500
200 IFP<12329THENA$=R1$:GOTO600
210 P=P+1:PS=PS+1
215 GOSUB700
220 POKEP,142:POKEPS,32
230 M=1:GOTO100
240 GOTO100
300 IFP>13286THENA$=R1$:GOTO600
310 P=P-1:PS=PS-1
315 GOSUB700
320 POKEP,158:POKEPS,32
330 M=2:GOTO100
340 GOTO100
400 IFP<12368THENA$=R1$:GOTO600
410 P=P-40:PS=PS-40
415 GOSUB700
420 POKEP,143:POKEPS,32
430 M=3:GOTO100
440 GOTO100
500 IFP>13247THENA$=R1$:GOTO600
510 P=P+40:PS=PS+40
515 GOSUB700
530 POKEP,159:POKEPS,32
540 M=4:GOTO100
550 GOTO100
600 N=1
605 PRINT:PRINT:PRINT"     SCORE "S
610 FORV=1TO500STEPN
620 SOUND(2,V):NEXTV
630 FORV=500TO1STEP-N
640 SOUND(1,V):NEXTV
645 POKE13312,N
650 N=N+5:IFN<60THEN610
680 PRINTCHR$(11)
690 PRINTA$:PRINT:PRINT"Your   Score "S:PRINT
691 IFS>RSTHENRS=S
692 PRINT"Record Score "RS:PRINT:PRINT:PRINT"PRESS 'S' TO START AGAIN......"
693 IFINKEY$<>"s"THEN693
695 GOTO1
700 IFPEEK(P)<>32THENA$=R2$:GOTO600
702 POKE INT(RND(1)*960)+12328,157:SOUND(1,1)
703 S=S+1
705 FORA=1TO20
706 NEXTA
710 RETURN
800 PRINTCHR$(11)"   *SPACE-COLLISION* Instructions."
810 PRINT:PRINT" Your 21st Century mission is to suvive"
820 PRINT"for as  long as possible amongst the  "
830 PRINT"the Space-Stations being built all the"
840 PRINT"time. DONT collide with them OR your  "
850 PRINT"own tracks.":PRINT:PRINT:PRINT
860 PRINT"MOVES:-         Up .... Q                             Down... Z"
870 PRINT"                Left... G                             Right.. H"
900 PRINT:PRINT:PRINT"      PRESS ANY KEY....."
920 IFINKEY$=""THEN920
930 GOTO1